fname = getOpenFileName caption:"Locate data file" filename:".txt"
f = openFile fname mode:"r"
counter = 0
atomradius = 0.5
bondradius = 0.25
disableSceneRedraw()

while (not eof f) do (
	aline = filterString (readLine f) " "
	linetype = aline[1]
	objecttype = aline[2]
	if (linetype == "a") do (
		x1 = aline[3] as float
		y1 = aline[4] as float
		z1 = aline[5] as float	
		atom = sphere pos:[x1,y1,z1] radius:atomradius name:objecttype		
	)
	if (linetype == "b") do (
		x1 = aline[3] as float
		y1 = aline[4] as float
		z1 = aline[5] as float	
		x2 = aline[6] as float
		y2 = aline[7] as float
		z2 = aline[8] as float	
		newLine = line()
		newline.name = objecttype
		newline.thickness = bondradius
		newline.renderable = on
		splineNum = addnewspline newline
		addknot newline splineNum #corner #line [x1,y1,z1]
		addknot newline splineNum #corner #line [x2,y2,z2]
		newLine
	)
	counter += 1
	if (mod counter 100 as integer == 0) do (
		displayTempPrompt (counter as string) 0
	)
)
close f
max tool zoomextents all
enableSceneRedraw()