// Entry code: xtweom
// Name      : Mike C. (A.K.A. Mike the Elder)
// Frame rate: 15
//   POV-Ray Short Code Competition #5 (Animation)  
//   Title: "Space: The Finite Frontier
//   Designed to run at 15 frames per second

light_source{-9999,1.6}
#local p=0;#while(p<360)
// "p" is the position for eac of the eight
//  identical "arms" of the space station.
//  Tossing in "hexagon" as a normal pattern
//  breaks up the simple shapes and gives
//  the impression of modular construction.
difference{union{sphere{z*9,1.6}sphere{z*1.6,2}cylinder{z*9,0,.6}cylinder{z*9,<7,0,6>,.6}
pigment{hexagon rgb.94,rgb 1,rgb.97 scale .1}normal{hexagon}} 
//  A box with a high rgb value, the corners of
//  which just stick out past the circumference
//  of the sphere, is subtracted from the spheres
//  to produce eight windows per sphere which 
//  appear either black or white (lights going 
//  on and off?) depending upon viewing angle.
box{<-1,-1,8>,<1,1,10>pigment{rgb 99}}
//  Over the course of the 100 frames, one arm 
//  rotates into the position of the next
//  (hopefully) giving the illusion that the
//  entire object rotates continuously.
rotate<0,p+44.55*clock,20>rotate x*36 translate<3,-4,22>}
#local p=p+45;#end  
//  The Planet: (No code margin left for fancy
//  features - "hexagon" allows for
//  three colors to be mixed with low code
//  overhead - no "color_map" needed.)
#local d=999999;sphere{<d*-.8,d*.7,d>,d pigment{hexagon 2*z+y,x+.5*z+y,x+y+z}}
//  Star field: Many spheres in highly asynchronous
//  Lissajous pattern.  It makes for slooooow
//  rendering, but was the only SHORT method that 
//  I could come up with for a star field that that I
//  liked. (Good looking pigment patterns needed long
//  color maps and scaling.) 
#while(p<d/17)
sphere{<2*d*sin(p/93),d*cos(p/.3),d*2>,d/400 pigment{rgb 4+5*cos(p/38)}}
#local p=p+13;#end