// Entry code: depjok
// Name      : Chassaing
// Frame rate: 15
// ===========================================
// Persistence Of Vision raytracer version 3.6
// Title:         Moebius
//                two spheres turn around the moebius strip
// Author:        Denis Chassaing <denis.chassaing@cassaneus.fr>
// Created:       04/jan/2008
// Last Modified: 17/jan/2008 
// scene for POVRay Short Code Contest
//           Round 5
//           The animation round! 
// ===========================================
// readable version

#default { pigment { rgbt<2,2,0,.97> } finish { ambient.2 reflection.4 phong 1 } normal { agate } }

light_source { -2,1 }                                           //Lighting  

union {

  sphere { 0,2 pigment { rgbt<1,1,0,.9> } normal { marble.3 } } //The middle sphere

  #declare i=0;                                                 //Loop counter
  #declare c=clock*360;
  #while(i<360)                                                 //Place 360 cylinders
    cylinder { -x,x,.1 rotate i/2*z translate 4*y rotate i*x }
    #declare i=i+2;                                             //Increment counter
  #end                                                          //End loop

  sphere { <-.8,0,0>.7 rotate (c+180)*z translate 4*y rotate (c*2+180)*x normal { marble.1 } }
  sphere { <0,.8,0>.7 rotate c*z translate 4*y rotate c*2*x normal { marble.1 } }

  rotate <c,c+120,90> translate 10*z}  

//
// Frame rate = 15
//
// File : moebius.ini
// 
// Input_File_Name=moebius.pov
// Output_File_Type=N
// Width=400
// Height=300
// Quality=9
// Antialias=on
// Antialias_Threshold=0.01
// Initial_Frame = 0
// Final_Frame = 99
// Initial_Clock = 0
// Final_Clock = 1 
// +FS
//
//