/*
 * The subject of the image, an open, somewhat frilly, isosurface.
 */
isosurface{
	function { x*y*z + 4*x + 2*y + z }
	contained_by{ sphere{ 0, 5 } }
	max_gradient 20
	open
	pigment {rgb 1}
}

/*
 * Yes, a waste of bytes, but the camera and the planes (below) need to
 * intersect at a 45-degree angle, and the rotation is simpler here than there.
 *
 * The focal point, 3.5, is an approximation of 5*sin(pi/4); that is, the point
 * on the isosurface's bounding sphere closest to the camera.
 */
camera{
	location 10
	look_at 0
	aperture 1
	focal_point 3.5
	blur_samples 50
}

/*
 * Located at 9, not 10, to save a byte. The double color (2) produces the glare
 * on the isosurface.
 */
light_source { 9, 2 }

/*
 * Three reflective planes, nested in a union to apply the reflection and save
 * bytes. The planes are parallel to the axes and tangent to the isosurface's
 * bounding sphere, making the isosurface seem much larger. (The actual
 * 'surface is only the frontmost section with the glare; everything else is
 * a reflection produced here.)
 */
union{
	plane { x, -5 }
	plane { y, -5 }
	plane { z, -5 }
	finish { reflection 1 }
}