Rendering Jerash

Written by Paul Bourke

AutoCAD Model courtesy of Chris Little, Stephanie Phan, Andrew Hutson, Frank Sears from the Melbourne University School of Architecture.

Photos of "the real thing" courtesy of Terrence Cooney, Nark O'Toole, Ella Bourke.


This model is based upon the amphitheatre in the center of the ancient Roman city of Jerash a few kilometers outside Amman in Jordan. The theatre could seat around 4000 people and is similar in design to the amphitheatre in the center of Amman.

The geometry for the model was imported into MicroStation and converted into a PovRay scene through the WRL export, this creates the cleanest and most convenient geometry output of all the formats provided by AutoCAD and MicroStation.

The rendering of the model served a number of purposes. It was a suitably complicated model to test some inhouse parallel rendering tools, it was used to create stereo pair images and animations for a virtual reality theatre, and it was use to experiment with precomputed interactive environments in stereo.

Right view
Top view
 
Side view
The triangular facets created byt the wrl to pov translator are encapsulated inside a "mesh {}" object as follows.
mesh {
   triangle {
      <-475.000000,0.000000,8659.983000>,
      <-475.000000,55.000000,8659.983000>,
      <475.000000,0.000000,8659.983000>
      texture { stonematerial }
   }
   :
   :
}
In total there were almost 200,000 triangular facets.

Stadium.pov

#include "colors.inc"
#include "skies.inc"
#declare VP = <0,5000,10000>;
#declare FP = <0,5000,9000>;
#include "camera.inc"
#include "lighting.inc"
#include "material.inc"
#include "stadium.inc"
Camera
camera {
   location VP
   up y
   right -4*x/3
   angle 60*1.25293
   sky <0,1,0>
   look_at FP
}
Lighting
global_settings {
   ambient_light
   rgb <1.0,1.0,1.0>
}
background {
   color rgb <0,0,0>
}
sky_sphere {
  /* Blue fade */
  pigment {
    gradient <0,1,0>
    color_map {
    [0 color rgb <0,1,1>]
    [1 color rgb <0,0,1>]
    }
  }
  /* Clouds */
  pigment {
    bozo
    turbulence 0.65
    octaves 6
    omega 0.7
    lambda 2
    color_map {
    [0.0 color rgbt <0.85, 0.85, 0.85, 0>]
    [0.2 color rgbt <0.75, 0.75, 0.75, 0>]
    [0.4 color rgbt <0.75, 0.75, 0.75, 0.5>]
    [1.0 color rgbt <1, 1, 1,1>]
    }
    scale <0.1,0.1,0.1>
  }
}
light_source {
   <3000,10000,-1000>
   color rgb <1,1,1>
}
Materials

Because of the AutoCAD origin of the model there was no useful colour information available. Fortunately the entire stadium is essentially built from the same material. An attempt was made to provide some interesting variation in the stone colour.

#declare thefinish = finish {
   ambient 0.4
   diffuse 1
   specular 0
   roughness .1
}

#declare thenormal = normal {
   bumps 0.01
   scale 100
}

#declare thepigment = pigment {
   bozo
   turbulence 1
   octaves 6
   lambda 3
   omega 0.5
   color_map {
   [0.00 color rgbt <196/256,195/256,149/256>]
   [0.80 color rgbt <188/256,180/256,131/256>]
   [0.90 color rgbt <154/256,149/256,109/256>]
   [1.00 color rgbt <121/256,102/256,062/256>]
   }
   scale 300
}

#declare stonematerial = texture {
   pigment { thepigment }
   finish  { thefinish  }
   normal  { thenormal  }
}

Images of this rendering for "cubeview" can be obtained from here as image set #9.

Anaglyphs
Red - Cyan
Red - Green
Red - Blue