/* --------------------------
Entry: 0030
WWW: 
Title: Stack of Julia Sets
Author:    

This is a 3D slice of a the 4D fractal consisting of all (complex,2nd power)Julia sets. It is, variating the constant c in the formula "z(n+1)=z(n)^2+c". In this case c changed from -1.5i to 1.5i, along the imaginary axis. This way, all symmetries of the Julia sets and Mandelbrot set are preserved: rotating 180° around the z-axis and mirroring over the xy-plane while at the same time rotating 90° round the z-axis
The version here is the result of a trial-and-error process. Some versions involved witing my own render engine, others pov-ray files with thousands of spheres or a 16GB mesh. The last error versions all used some of pov-ray's build-in support for Julia sets: a stack of cylinders with a julia texture,
a stack of intersections between a julia_fractal and a cylinder, and the last version: a stack of isosurfaces, using the julia pattern as a function.
---------------------------*/

#declare Dikte=0.001;
#declare Z=-1.5;
#while (Z<=1.5)
#undef jF1
#declare jF1 = function{pattern{julia <0,Z-Dikte>,16 interior 0,1 exterior 1,1}}
isosurface{
function {0.9-jF1(x,y,z)}
contained_by{box{<-2,-2,Z-Dikte>,<2,2,Z+Dikte>}}
accuracy 0.001
max_gradient 150
texture{pigment{agate scale 0.2 color_map{[0.0 rgb<1,1,1>][1.0 rgb<0.7,0.7,0.7>]}} finish{ambient 0.5}}
}
#declare Z = Z+2*Dikte;
#end
camera{location<-2,-3,5> look_at <0,0,0>sky z}
light_source{<-10,-10,100>,rgb<1,1,1>}