/* --------------------------
Entry: 0023
WWW: 
Title: Pernelle
Author: Noe Falzon

Spheres in spheres in spheres... This cristalline and simple fractalicity (fractalism, fractalicism... ;) ) is named after my sister's name whose birthday occurs today.
There is a simple use of a recursive macro, who calls itself a number of time specified by a variable.
The more you give a high value to max_trace_level, the more you'll get a light image, with a thin dark ray in the middle, along the little spheres.
Each sphere is transparent and reflective, which gives this aspect to the whole object.
There is a white plane beneath, to help the transparency effect.
---------------------------*/

// Persistence of Vision Ray Tracer Scene Description File
// File: fractal.pov
// Vers: 3.5
// Desc: For the Bourke Fractal Contest
// Date: 16/04/2004 pour le rendu final

#version 3.5;
global_settings {
  assumed_gamma 1.0
  max_trace_level 10
}
// ----------------------------------------
camera {
  location  <0.4, 0.4, -0.2>
  right     x*image_width/image_height
  look_at   <0.0, 0.0,  0.0>
}
sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.7 rgb <0.0,0.1,0.8>]
    }
  }
}
light_source {
  <0, 0, 0>
  color rgb <1, 1, 1>
  translate <-30, 30, -30>
}
// ----------------------------------------
plane {
  y, -1
  pigment { color rgb 1 }
}
#macro maSphere(zPos, zIter, zRad)
 sphere { zPos, zRad }
 
 #if (zIter > 0) 
  maSphere ( zPos+0.5*zRad*x, zIter-1 zRad*0.5 )
  maSphere ( zPos-0.5*zRad*x, zIter-1 zRad*0.5 )
 #end
#end
union { maSphere(0,7,1) texture {pigment {color rgbft <0.8,0.8,1,0.9,0.1>} finish {reflection 0.3}}}