/* --------------------------
Entry: 0015
WWW: http://
Title: Frozen Light
Author: Steve Shoopak
A collection of realized photons coalesce into the fluidic metal of a frozen snowflake.
Most fractals are achieved through recursion, or by means of well-crafted iteration; however, I have chosen to take a random approach using constraint points.  Each luminescent sphere is placed halfway between the last locus and a control point chosen at random from the six edge points.  These quanta are placed in two dimensions, using reflection and emission sums to achieve the 3d effect seen in the image.
---------------------------*/

// Persistence of Vision Ray Tracer Scene Description File
// File: frozenlight.pov
// Vers: 3.5
// Desc:
// 
//     A collection of realized photons coalesce into the fluidic metal of a 
//     frozen snowflake.
//
//     Most fractals are achieved through recursion, or by means of well-
//     crafted iteration; however, I have chosen to take a random approach
//     using constraint points.  Each luminescent sphere is placed halfway
//     between the last locus and a control point chosen at random from the
//     six edge points.  These quanta are placed in two dimensions, using
//     reflection and emission sums to achieve the 3d effect seen in the
//     image.
//
// Date: April 12th, 2004
// INI settings
//Output_File_Type=C
//Width=800
//Height=800
//Quality=9
//Antialias=on
//Antialias_Threshold=0.001
// +H800 +W800 -Q9 +A0.001
camera {
  location <0,0,-12>
  look_at <0,0,0>
}
light_source {
  0*x
  color rgb 1
  translate <10,100,-120>
}
#declare r1 = seed(0);
#declare r2 = seed(1);
#declare r3 = seed(2);
#declare grid = array[6] {
  <cos(radians(  0)),sin(radians(  0)),0>,
  <cos(radians( 60)),sin(radians( 60)),0>,
  <cos(radians(120)),sin(radians(120)),0>,
  <cos(radians(180)),sin(radians(180)),0>,
  <cos(radians(240)),sin(radians(240)),0>,
  <cos(radians(300)),sin(radians(300)),0>,
}
#declare vec = <0,0,0>;
#declare i = 0;
union {
  #while(i<10000)
    #local r = int(rand(r1)*6);
    #declare vec = (vec + grid[r])/2;
    sphere {
      0,1
      hollow
      material {
        texture {
          normal {
            granite
          }
          pigment {
            color rgbt 1
          }
          finish {
            diffuse 0
            ambient 0
            reflection 0.1
            specular 0.2
            roughness 0.001
          }
        }
        interior {
          media {
            intervals 30
            ratio 0.9
            samples 2,4
            confidence 0.9
            variance 1.0/128.0
            method 1
            emission <1,1,1> * 8
            density {
              spherical
              turbulence 0
              density_map {
                [0.0 color rgb 0.0 ]
                [0.2 color rgb 0.5 ]
                [0.3 color rgb 0.0 ]
                [1.0 color rgb 1.0 ]
              }
            }
          }
        }
      }
      scale 0.1
      translate vec * 4
    }
    #declare i = i + 1;
  #end
  rotate -z*30
}