/* --------------------------
Entry: 0007
WWW: 
Title: Oops, I dropped it on the floor!
Author: Juha Nieminen
  Since I'm not artistically very talented nor I know too much about making fractals, I resorted to a cheap trick: Photorealism (or sort of). Perhaps that will give me a vote or two... :)
  The object itself is naturally a (3D slice of a) 4D julia fractal. Nothing unconventional per se, and not really fancy in itself, but when used in a proper scene with some photorealistic effects (lighting, floor shape and texture, focal blur) it looks like a cool mole of metal.
---------------------------*/

camera
{ right x
  location <-1, 2.8, -3.5>*1.2 look_at y*.5
  focal_point 0 blur_samples 40 aperture .35
}
light_source
{ <23,15,-20>, 1
  area_light x*5,y*5,12,12 circular orient jitter adaptive 1
}
light_source
{ <23,15,20>, <.3,.4,.5>
  area_light x*5,y*5,12,12 circular orient jitter adaptive 1
}
light_source
{ <-15,45,35>, <.8,.6,.3>
  area_light x*15,y*15,12,12 circular orient jitter adaptive 1
}
julia_fractal
{ <-.4, .2, .3, -.2>
  quaternion sqr
  max_iteration 8
  precision 50
  pigment { rgb .5 }
  finish
  { specular 2 roughness .02 metallic
    reflection { .2, .8 }
  }
  rotate z*-20
  translate y*.9
}
#declare noise3d = function { internal(76) }
#declare Plank=
  isosurface
  { function { pow(x, 10)+pow(y*5, 10)-(1-.5*noise3d(x*20,y*10,z)) }
    contained_by { box { -<1,1/5,50>, <1,1/5,50> } }
    max_gradient 50
  }
union
{ #declare Seed = seed(0);
  #declare Ind = 0;
  #while(Ind < 15)
    object { Plank translate<-8+2*Ind, 0, -10*rand(Seed)> }
    #declare Ind = Ind+1;
  #end
  texture
  { pigment
    { wood color_map
      { [0 rgb <.8,.5,.3>][.5 rgb <.7,.45,.2>][1 rgb <.65,.4,.2>]
      }
      turbulence .5
      scale <1,1,10>
    }
    finish { specular .8 reflection { .1, .3 } }
    normal
    { average normal_map
      { [1 bumps .4 scale <.1, .1, 1>]
        [1 dents 1 scale .1]
      }
    }
  }
  texture
  { pigment
    { bozo color_map
      { [0 rgb 0 transmit .5]
        [.5 rgbt 1]
      }
      scale 5
      warp { turbulence 2 }
      scale 1/5
    }
  }
}